Document

Operation	:	Linux server.tradinguniversity.rs 3.10.0-1160.119.1.vz7.224.4 #1 SMP Mon Sep 30 15:36:27 MSK 2024 x86_64
Software	:	Apache
Server IP	:	68.66.251.59 \| Your IP: 216.73.216.158
Domains	:	4 Domain
Permission	:	[ drwxr-xr-x ]

/ usr / share / awk /

Web File Manager

主页上传上传 V2 命令行

getopt.awk

# getopt.awk --- Do C library getopt(3) function in awk
#                Also supports long options.
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
#
# Initial version: March, 1991
# Revised: May, 1993
# Long options added by Greg Minshall, January 2020

# External variables:
#    Optind -- index in ARGV of first nonoption argument
#    Optarg -- string value of argument to current option
#    Opterr -- if nonzero, print our own diagnostic
#    Optopt -- current option letter

# Returns:
#    -1     at end of options
#    "?"    for unrecognized option
#    <s>    a string representing the current option

# Private Data:
#    _opti  -- index in multiflag option, e.g., -abc
function getopt(argc, argv, options, longopts,    thisopt, i, j)
{
    if (length(options) == 0 && length(longopts) == 0)
        return -1                # no options given

if (argv[Optind] == "--") {  # all done
        Optind++
        _opti = 0
        return -1
    } else if (argv[Optind] !~ /^-[^:[:space:]]/) {
        _opti = 0
        return -1
    }
    if (argv[Optind] !~ /^--/) {        # if this is a short option
        if (_opti == 0)
            _opti = 2
        thisopt = substr(argv[Optind], _opti, 1)
        Optopt = thisopt
        i = index(options, thisopt)
        if (i == 0) {
            if (Opterr)
                printf("%c -- invalid option\n", thisopt) > "/dev/stderr"
            if (_opti >= length(argv[Optind])) {
                Optind++
                _opti = 0
            } else
                _opti++
            return "?"
        }
        if (substr(options, i + 1, 1) == ":") {
            # get option argument
            if (length(substr(argv[Optind], _opti + 1)) > 0)
                Optarg = substr(argv[Optind], _opti + 1)
            else
                Optarg = argv[++Optind]
            _opti = 0
        } else
            Optarg = ""
        if (_opti == 0 || _opti >= length(argv[Optind])) {
            Optind++
            _opti = 0
        } else
            _opti++
        return thisopt
    } else {
        j = index(argv[Optind], "=")
        if (j > 0)
            thisopt = substr(argv[Optind], 3, j - 3)
        else
            thisopt = substr(argv[Optind], 3)
        Optopt = thisopt
        i = match(longopts, "(^|,)" thisopt "($|[,:])")
        if (i == 0) {
            if (Opterr)
                 printf("%s -- invalid option\n", thisopt) > "/dev/stderr"
            Optind++
            return "?"
        }
        if (substr(longopts, i+1+length(thisopt), 1) == ":") {
            if (j > 0)
                Optarg = substr(argv[Optind], j + 1)
            else
                Optarg = argv[++Optind]
        } else
            Optarg = ""
        Optind++
        return thisopt
    }
}
BEGIN {
    Opterr = 1    # default is to diagnose
    Optind = 1    # skip ARGV[0]

# test program
    if (_getopt_test) {
        _myshortopts = "ab:cd"
        _mylongopts = "longa,longb:,otherc,otherd"

while ((_go_c = getopt(ARGC, ARGV, _myshortopts, _mylongopts)) != -1)
            printf("c = <%s>, Optarg = <%s>\n", _go_c, Optarg)
        printf("non-option arguments:\n")
        for (; Optind < ARGC; Optind++)
            printf("\tARGV[%d] = <%s>\n", Optind, ARGV[Optind])
    }
}

Name	Type	Size	Owner/Group	Permission	Last Modified	Actions
.	dir	-	root/root	drwxr-xr-x	2023-05-15 06:36:07
..	dir	-	root/root	drwxr-xr-x	2025-06-06 10:33:52
assert.awk	text/plain	383 B	root/root	-rw-r--r--	2020-04-14 11:44:15
bits2str.awk	text/plain	334 B	root/root	-rw-r--r--	2020-04-14 11:44:15
cliff_rand.awk	text/plain	307 B	root/root	-rw-r--r--	2020-04-14 11:44:15
ctime.awk	text/plain	234 B	root/root	-rw-r--r--	2020-04-14 11:44:15
ftrans.awk	text/plain	315 B	root/root	-rw-r--r--	2020-04-14 11:44:15
getopt.awk	text/plain	3.2 KB	root/root	-rw-r--r--	2020-04-14 11:44:15
gettime.awk	text/plain	2.43 KB	root/root	-rw-r--r--	2020-04-14 11:44:15
group.awk	text/plain	1.72 KB	root/root	-rw-r--r--	2022-03-30 10:25:14
have_mpfr.awk	text/plain	221 B	root/root	-rw-r--r--	2020-04-14 11:44:15
inplace.awk	text/plain	2.29 KB	root/root	-rw-r--r--	2020-04-14 11:44:15
intdiv0.awk	text/plain	462 B	root/root	-rw-r--r--	2020-04-14 11:44:15
join.awk	text/plain	378 B	root/root	-rw-r--r--	2020-04-14 11:44:15
libintl.awk	text/x-c	238 B	root/root	-rw-r--r--	2020-04-14 11:44:15
noassign.awk	text/plain	422 B	root/root	-rw-r--r--	2020-04-14 11:44:15
ns_passwd.awk	text/plain	1.25 KB	root/root	-rw-r--r--	2020-04-14 11:44:15
ord.awk	text/plain	937 B	root/root	-rw-r--r--	2020-04-14 11:44:15
passwd.awk	text/plain	1.17 KB	root/root	-rw-r--r--	2022-03-30 10:25:14
processarray.awk	text/plain	355 B	root/root	-rw-r--r--	2020-04-14 11:44:15
quicksort.awk	text/plain	1.01 KB	root/root	-rw-r--r--	2020-04-14 11:44:15
readable.awk	text/plain	489 B	root/root	-rw-r--r--	2020-04-14 11:44:15
readfile.awk	text/plain	267 B	root/root	-rw-r--r--	2020-04-14 11:44:15
rewind.awk	text/plain	404 B	root/root	-rw-r--r--	2020-04-14 11:44:15
round.awk	text/plain	661 B	root/root	-rw-r--r--	2020-04-14 11:44:15
shellquote.awk	text/plain	472 B	root/root	-rw-r--r--	2020-04-14 11:44:15
strtonum.awk	text/plain	1.42 KB	root/root	-rw-r--r--	2020-04-14 11:44:15
walkarray.awk	text/plain	214 B	root/root	-rw-r--r--	2020-04-14 11:44:15
zerofile.awk	text/plain	424 B	root/root	-rw-r--r--	2020-04-14 11:44:15